echo off
REM VIDEO/AUDIO-RECORDER MIT TIMER FÜR AUFNAHMEN MIT DEM VLC-PLAYER. SIGNALQUELLE: DVB-T-Fernsehen und Internet-Radio
REM Bitte EINSTELLUNGEN und HINWEISE weiter unten beachten!
REM Version 2015.06.08

REM ### DATEN DER AUFNAHME ############# Folgende 6 set-Kommandos zwischen = und " editieren. Leerzeichen unzulässig!  ###############
	
	REM Eine Senderkennung laut Programmlisten (s. u.) eintragen.
	set "Sender=BBC-Radio-One" 			    	            
  
	REM Dateinamen (ohne Endung) eintragen, unter dem die Aufnahme gespeichert werden soll. Bindestrich statt Leerzeichen.
	set "Dateiname=Probeaufnahme-BBC"

	REM Datum des Aufnahmebeginns eintragen (TT.MM.JJJJ).
	set "DatumAufnahmebeginn=08.06.2015"             

	REM Uhrzeit des Aufnahmebeginns eintragen (hh:mm).
	set "UhrzeitAufnahmebeginn=15:13"                

	REM Aufnahmedauer (in ganzen Minuten) eintragen.
	set "AufnahmedauerMinuten=1"                   
 
	REM Verhalten des Rechners nach Aufnahme eintragen. 0: Rechner bleibt an, 1: Rechner fährt herunter.
	set "Herunterfahren=0"
	
	REM Speichern nicht vergessen!
	
REM ### DATEN DER AUFNAHME, ENDE #######################################################################################################

REM ### EINSTELLUNGEN ##################################################################################################################
	REM Zielverzeichnis eintragen, am Ende ohne Backslash. Beispiel: E:\Music\VLC-Stream-Aufnahmen
	set "Zielverzeichnis=E:\Music\VLC-Stream-Aufnahmen"

    REM Programmliste (Fernsehen) für DVB-T-Sender (hier: Teutoburger Wald,Bielstein) 
	REM Die typische Reichweite eines DVB-T-Senders beträgt 40 km. Liste nach Empfängerstandort ergänzen.
	REM   Senderfrequenzen in Deutschland siehe REM 1, Service-IDs eines Bouquets siehe REM 2 und REM 3 
	REM 1 http://www.dvb-t-portal.de/Regionen/index.php
	REM 2 https://www.vlc-forum.de/index.php/Thread/908-tv-tv-empfang-f%C3%BCr-dvb-t/
	REM 3 http://www.vdr-wiki.de/wiki/index.php/Kategorie:Channels.conf_DVBT    Frequenz: 1. Zahl, Service-ID: vor dem drittletzten Doppelpunkt stehende Zahl
	IF %Sender%==ARD   				set Frequenz=514 & set ServiceID=256   & set endg=ts
	IF %Sender%==ZDF   				set Frequenz=570 & set ServiceID=514   & set endg=ts
	IF %Sender%==3sat  				set Frequenz=570 & set ServiceID=515   & set endg=ts
	IF %Sender%==arte  				set Frequenz=514 & set ServiceID=2     & set endg=ts
	IF %Sender%==Phoenix  			set Frequenz=514 & set ServiceID=3     & set endg=ts
	IF %Sender%==EinsFestival   	set Frequenz=514 & set ServiceID=5     & set endg=ts
	IF %Sender%==ZDFinfo 			set Frequenz=570 & set ServiceID=516   & set endg=ts
	IF %Sender%==neoKiKa			set Frequenz=570 & set ServiceID=517   & set endg=ts
	IF %Sender%==MDR				set Frequenz=554 & set ServiceID=100   & set endg=ts
	IF %Sender%==NDR				set Frequenz=554 & set ServiceID=129   & set endg=ts
	IF %Sender%==SWR				set Frequenz=554 & set ServiceID=226   & set endg=ts
	IF %Sender%==WDR-BI				set Frequenz=554 & set ServiceID=258   & set endg=ts
	IF %Sender%==WDR-SG				set Frequenz=554 & set ServiceID=264   & set endg=ts
	IF %Sender%==Pro7Hannover		set Frequenz=658 & set ServiceID=16403 & set endg=ts
	
	REM Programmliste für Internet-Radio
	REM URL unter Stationsnamen recherchieren
	IF %Sender%==WDR3				set Frequenz=0   & set SenderURL=http://wdr-3.akacast.akamaistream.net/7/47/119437/v1/gnl.akacast.akamaistream.net/wdr-3 & set endg=mp3
	IF %Sender%==WDR4				set Frequenz=0   & set SenderURL=http://wdr-4.akacast.akamaistream.net/7/42/119438/v1/gnl.akacast.akamaistream.net/wdr-4 & set endg=mp3
	IF %Sender%==RadioSwissClassic	set Frequenz=0   & set SenderURL=http://stream.srg-ssr.ch/m/rsc_de/mp3_128												 & set endg=mp3
	IF %Sender%==BRKlassik	        set Frequenz=0   & set SenderURL=http://streams.br.de/br-klassik_2.m3u								     				 & set endg=mp3	
	IF %Sender%==Birds	            set Frequenz=0   & set SenderURL=http://yradio.vtuner.com/pls/pls69401.m3u			   									 & set endg=mp3
	IF %Sender%==BBC-Radio-One	    set Frequenz=0   & set SenderURL=http://yradio.vtuner.com/pls/pls1357.m3u			   									 & set endg=mp3	
		
REM ### EINSTELLUNGEN-ENDE #########################################################################################################################

REM ### HINWEISE ###################################################################################################################################
	REM Dateiendung "txt" in "bat" ändern.
	REM Diese bat-Datei wendet sich an Nutzer mit Grundkenntnissen in Batch-Programmierung. Alle anderen beachten bitte: 
	REM Sie bearbeiten bei Ihren Eintragungen in einen Programmcode. Änderungen außerhalb der Batch-Syntax führen zum Misserfolg.
	REM Videodateien werden als *.ts gespeichert, Audiodateien als *.mp3.
	REM Wenn Sie nicht in der Nähe des DVB-T-Senders Teutoburger-Wald-Bielstein (nahe Detmold) empfangen, ergänzen Sie die Fernseh-Programmliste um die
	REM interessierenden Stationen. Die vorhandene Liste kann bestehen bleiben.
	REM Sich überlappende mp3-Aufnahmen sind mit mehreren, verschieden benannten bat-Dateien möglich.
	REM Für Sofortaufnahme das Datum des Vortags eintragen, Uhrzeit beliebig. 
	REM Tipp: Eintragungen einer zeitgesteuerten Aufnahme mittels kurzer Sofortaufnahme kontrollieren.
	REM Tipp: Bei DVB-T-Aufnahmen Anschließen des Empfängers (z. B. USB-Stick mit Antenne) nicht vergessen.
	REM Tipp: Speichern der Einträge vor dem Starten nicht vergessen!
	REM Tipp: Die vom Internet-Provider ausgelöste Zwangsunterbrechung (üblicherweise zwischen 3 und 5 Uhr nachts) bricht Aufnahmen ab. Das Intervall
    REM 	  kann mit der Router-Softwäre geändert werden.	
REM ### HINWEISE-ENDE ###############################################################################################################################

REM Hiernach editieren nur noch Entwickler ;)
set Dateiname=%Dateiname%.%endg%	                
set "batPfad=%~f0"
title %batPfad%

echo Sender: %Sender%
echo Dateiname: %Dateiname% 
echo Datum Aufnahmebeginn: %DatumAufnahmebeginn%
echo Uhrzeit Aufnahmebeginn: %UhrzeitAufnahmebeginn% 
echo Aufnahmedauer in Minuten: %AufnahmedauerMinuten% 
echo Herunterfahren: %Herunterfahren% 
echo Zielverzeichnis: %Zielverzeichnis%
echo cmd-Fenstertitel: %batPfad%

REM Format von %DatumAufnahmebeginn% auf JJJJ.MM.TT umstellen
set "DatumAufnahmebeginn=%DatumAufnahmebeginn:~6,4%.%DatumAufnahmebeginn:~3,2%.%DatumAufnahmebeginn:~0,2%"
set ZeitAufnahmebeginn="%DatumAufnahmebeginn%_%UhrzeitAufnahmebeginn%"

set /a "Frequenz = 1000000*%Frequenz%"
if "%Frequenz%" GTR "0" set SenderURL=dvb-t://frequency=%Frequenz%:bandwidth=0 :dvb-adapter=0 :live-caching=1000 :program=%ServiceID%
set /a "AufnahmedauerSekunden=60*%AufnahmedauerMinuten%" 
echo Datum und Uhrzeit bei Warte-Beginn: %date% %time%

:WARTESCHLEIFE
	set "Uhrzeit=%time%"
	REM Format von %Uhrzeit% auch im Bereich einstelliger Stunden auf hh:mm setzen (microsoft-Syntax liefert dafür  0:00... 9:59 Uhr mit führendem Leerzeichen!):
    if "%Uhrzeit:~0,1%"==" "    set "Uhrzeit=0%time:~1,7%"
    set Zeit="%date:~6,4%.%date:~3,2%.%date:~0,2%_%Uhrzeit%"
	REM Minütliche Anzeige des Aufnahmebeginns
	set "Sekunden=%Zeit:~18,2%"
	if "%Sekunden%" GEQ "55" echo Aufnahmebeginn am %DatumAufnahmebeginn% um %UhrzeitAufnahmebeginn% Uhr 
	
	if %Zeit% GEQ %ZeitAufnahmebeginn% (
	START ""  "C:\Program Files (x86)\VideoLAN\VLC\vlc.exe" -vvv %SenderURL% --sout %Zielverzeichnis%\%Dateiname% 
	ping -n %AufnahmedauerSekunden% 127.0.0.1 > NUL
	if %Herunterfahren%==1 shutdown.exe /s /t 00
	taskkill /F /FI "WindowTitle  eq  %batPfad%" /T	
	) else (
    REM Abfrageintervall  
	timeout /T 5 /nobreak
	goto WARTESCHLEIFE
	)
REM Warteschleifenende