VLC konvertiert nicht

@echo off

rem Diese Batchdatei ermoeglicht das Rippen aller Tracks einer Audio-CD nach MP3 oder WAV.
rem Die Pfade fuer die vlc.exe, das optische Laufwerk und den Zielordner muessen angepasst werden.
rem Sie muss mit einer MS-DOS-Codepage gespeichert sein (z.B. Codepage 850, Ansi, DOS-Latin-1).

rem Autor: kodela

rem Laufende Nummer auf Null und Dateiname auf leeren String setzen.
set /a n=0
set f=""

rem ### Laufwerk und Pfad für auszuefuehrende vlc.exe einstellen.           ### 
D:
cd D:\Tools\VLC\vlc-2.1.5


rem ### Zielordner anpassen - der Pfadname darf keine Leerstellen enthalten ###
rem ### und der angegebene Ordner muss vorhanden sein.                      ###
set p=D:\Rudi\Musik\Neue_CD\

rem Alle Tracks der CD bearbeiten.
rem ### Den Pfad fuer das optische Laufwerk anpassen (G:\).                 ###
for /R G:\ %%T in (*.cda) do (call :sub_transcode "%%T")

rem Nach Beendigung des Jobs zum Ende springen.
goto :eof

:sub_transcode
rem Hier beginnt die Bearbeitung eines Tracks.

rem Naechste laufende Nummer festlegen.
call set /a n=n+1

rem Vornull fuer einstellige laufende Nummer beruecksichtigen.
if %n% gtr 9 goto :ohne_Null

rem Wenn laufende Nummer einstellig ist:
call set f=%p%Track_0%n%
goto :transcode

rem Laufende Nummer ist zweistellig:
:ohne_Null   
call set f=%p%Track_%n%

:transcode  
rem Standard-Interface wird angezeigt.
rem Soll das dieses nicht angezeigt werden, den Parameter "-I http" setzen.


rem Transkodierung nach MP3
rem Bearbeitung des naechsten Stueckes anzeigen.
rem echo transcodiere %1 zu %f%.mp3
rem call vlc.exe cdda:///G:/ --cdda-track=%n% :sout=#transcode{vcodec=none,acodec=mp3,ab=128,channels=2,samplerate=44100}:std{access="file",mux=raw,dst=%f%.mp3} vlc://quit

 
rem Transkodierung nach WAV
rem Bearbeitung des naechsten Stueckes anzeigen.
echo transcodiere %1 zu %f%.wav
call vlc.exe cdda:///G:/ --cdda-track=%n% :sout=#transcode{vcodec=none,acodec=s16l,ab=224,channels=2,samplerate=48000}:std{access="file",mux=wav,dst=%f%.wav} vlc://quit

:eof