echo off
REM VIDEO/AUDIO-RECORDER MIT TIMER FÜR AUFNAHMEN MIT DEM VLC-PLAYER; SIGNALQUELLE: DVB-T ODER INTERNET
REM Dateiname: VLC-Recorder-2015-04-13.bat
REM  Dateiendung der Aufzeichnungsdateien: ts bei Video, mp3 bei Audio
REM Zielverzeichnis für aufgenommene Dateien ist E:\Music\VLC-Stream-Aufnahmen\
REM Die Senderliste (s. Skriptende) gilt für den Sender Bielstein im Teutoburger Wald. Sie muss bei Ortswechsel angepasst werden.

REM ##########################################################################################################################################
REM ### EINGABE-ANFANG #############   Nur die set-Kommandos zwischen = und " editieren. Leerzeichen verboten!  ##############################

REM Einen Sender laut Senderliste unten eingeben.
set "Sender=arte" 			    	            
echo Sender: %Sender%  

REM Dateinamen (ohne Endung) eingeben, unter dem die Aufnahme gespeichert werden soll.
set "Dateiname=arteTest"
echo Dateiname: %Dateiname% 

REM Datum des Aufnahmebeginns eingeben (TT.MM.JJJJ).
REM (Für Sofortaufnahme Datum des Vortags eingeben.)
set "DatumAufnahmebeginn=13.04.2015"             
echo Datum Aufnahmebeginn: %DatumAufnahmebeginn% 

REM Uhrzeit des Aufnahmebeginns eingeben (hh:mm).
set "UhrzeitAufnahmebeginn=09:59"                
echo Uhrzeit Aufnahmebeginn: %UhrzeitAufnahmebeginn% 

REM Aufnahmedauer (in ganzen Minuten) eingeben.
set "AufnahmedauerMinuten=1"                   
echo Aufnahmedauer in Minuten: %AufnahmedauerMinuten%  

REM Verhalten des Rechners nach Aufnahme eingeben. 0: Rechner bleibt an, 1: Rechner fährt herunter.
set "Herunterfahren=0"			                
echo Herunterfahren: %Herunterfahren% 

REM ### EINGABE-ENDE #########################################################################################################################
REM ##########################################################################################################################################

REM Format von %DatumAufnahmebeginn% auf JJJJ.MM.TT umstellen
set "DatumAufnahmebeginn=%DatumAufnahmebeginn:~6,4%.%DatumAufnahmebeginn:~3,2%.%DatumAufnahmebeginn:~0,2%"
set ZeitAufnahmebeginn="%DatumAufnahmebeginn%_%UhrzeitAufnahmebeginn%"

call :SENDERLISTE

set /a "Frequenz = 1000000*%Frequenz%"
if "%Frequenz%" GTR "0" set SenderURL=dvb-t://frequency=%Frequenz%:bandwidth=0 :dvb-adapter=0 :live-caching=1000 :program=%ServiceID%
set /a "AufnahmedauerSekunden=60*%AufnahmedauerMinuten%" 
echo Datum und Uhrzeit bei Warte-Beginn: %date% %time%

:WARTESCHLEIFE
	set "Uhrzeit=%time%"
	REM Format von %Uhrzeit% auch im Bereich einstelliger Stunden auf hh:mm setzen (microsoft-Syntax liefert dafür  0:00... 9:59 Uhr mit führendem Leerzeichen)
    if "%Uhrzeit:~0,1%"==" "    set "Uhrzeit=0%time:~1,4%"
    set Zeit="%date:~6,4%.%date:~3,2%.%date:~0,2%_%Uhrzeit%"
	if %Zeit% GEQ %ZeitAufnahmebeginn% (
	START ""  "C:\Program Files (x86)\VideoLAN\VLC\vlc.exe" -vvv %SenderURL% --sout E:\Music\VLC-Stream-Aufnahmen\%Dateiname% 
	timeout /T   %AufnahmedauerSekunden%
	TASKKILL /F /IM vlc.exe
	) else (
	timeout /T 5 /nobreak
	goto WARTESCHLEIFE
	)
REM Warteschleifenende
if %Herunterfahren%==1 shutdown.exe /s /t 00
goto :ENDE

:SENDERLISTE
	REM  DVB-T-Fernsehen  *.ts, Sender Teutoburger Wald (Bielstein)
	IF %Sender%==ARD   				set Frequenz=514 & set ServiceID=256 & set endg=ts
	IF %Sender%==ZDF   				set Frequenz=570 & set ServiceID=514 & set endg=ts
	IF %Sender%==3sat  				set Frequenz=570 & set ServiceID=515 & set endg=ts
	IF %Sender%==arte  				set Frequenz=514 & set ServiceID=2   & set endg=ts
	IF %Sender%==Phoenix  			set Frequenz=514 & set ServiceID=3   & set endg=ts
	IF %Sender%==EinsFestival   	set Frequenz=514 & set ServiceID=5   & set endg=ts
	IF %Sender%==ZDFinfo 			set Frequenz=570 & set ServiceID=516 & set endg=ts
	IF %Sender%==neoKiKa			set Frequenz=570 & set ServiceID=517 & set endg=ts
	IF %Sender%==MDR				set Frequenz=554 & set ServiceID=100 & set endg=ts
	IF %Sender%==NDR				set Frequenz=554 & set ServiceID=129 & set endg=ts
	IF %Sender%==SWR				set Frequenz=554 & set ServiceID=226 & set endg=ts
	IF %Sender%==WDR-BI				set Frequenz=554 & set ServiceID=258 & set endg=ts
	IF %Sender%==WDR-SG				set Frequenz=554 & set ServiceID=100 & set endg=ts

	REM  Internet-Radio  *.mp3
	IF %Sender%==WDR3				set Frequenz=0   & set SenderURL=http://wdr-3.akacast.akamaistream.net/7/47/119437/v1/gnl.akacast.akamaistream.net/wdr-3 & set endg=mp3
	IF %Sender%==WDR4				set Frequenz=0   & set SenderURL=http://wdr-4.akacast.akamaistream.net/7/42/119438/v1/gnl.akacast.akamaistream.net/wdr-4 & set endg=mp3
	IF %Sender%==RadioSwissClassic	set Frequenz=0   & set SenderURL=http://stream.srg-ssr.ch/m/rsc_de/mp3_128												 & set endg=mp3
	
	set Dateiname=%Dateiname%.%endg%
goto :eof

:ENDE

REM   DVB-T: Senderfrequenzen siehe REM 1, Service-IDs eines Bouquets siehe REM 2 
REM 1 http://www.dvb-t-portal.de/Regionen/index.php
REM 2 https://www.vlc-forum.de/index.php/Thread/908-tv-tv-empfang-f%C3%BCr-dvb-t/
REM   https://www.vlc-forum.de/index.php/Thread/902-A6-H%C3%A4ufig-gestellte-Fragen-zum-VLC-Player/
REM   Dieses Skript entstand April 2015 mit Hilfe des VLC-Forum-Threads https://www.vlc-forum.de/index.php/Thread/1807-URL-von-3sat   beraten von kodela