echo off
:: VIDEO/AUDIO-RECORDER MIT TIMER FÜR AUFNAHMEN MIT DEM VLC-PLAYER. SIGNALQUELLE: DVB-T-Fernsehen und Internet-Radio
:: ==================================================================================================================
:: EINSTELLUNGEN und HINWEISE weiter unten beachten!
:: Version 2015-08-17

:: ### DATEN DER AUFNAHME ############# Folgende 6 set-Kommandos zwischen = und " editieren. Leerzeichen unzulässig!  ###############
	
	:: Eine Senderkennung laut Programmlisten (s. u.) eintragen.
	set "Sender=BBC1" 			    	            
  
	:: Dateinamen (ohne Endung) eintragen, unter dem die Aufnahme gespeichert werden soll. Erlaube Zeichen z.B.    0-9-a-z-A-Z.-_!-(-)-$-@     KEINE LEERZEICHEN, keine Umlaute
	:: Empfehlung:  nur aA1_-() nutzen! 	
	set "Dateiname=Testaufnahme"
	 
	:: Datum des Aufnahmebeginns eintragen (TT.MM.JJJJ).
	set "DatumAufnahmebeginn=17.08.2015"             

	:: Uhrzeit des Aufnahmebeginns eintragen (hh:mm).
	set "UhrzeitAufnahmebeginn=18:00"                

	:: Aufnahmedauer (in ganzen Minuten) eintragen.
	set "AufnahmedauerMinuten=1"                   
 
	:: Verhalten des Rechners nach Aufnahme eintragen. 0: Rechner bleibt an, 1: Rechner fährt herunter.
	set "Herunterfahren=0"
	
:: ### DATEN DER AUFNAHME, ENDE #######################################################################################################
:: Speichern nicht vergessen!	
:: file://E:/Music/VLC-Stream-Aufnahmen/VLC-Recorder/VLC-Recorder-Elmshorn-Kopie.bat    Startlink (funktioniert z. B. in Notepad++)  	
:: Vor erstem Gebrauch Zielverzeichnis und Senderliste (s. Einstellungen unten) sowie den Pfad dieser batch-Datei in der vorigen Zeile lokal anpassen!


:: ### EINSTELLUNGEN ##################################################################################################################
	:: Zielverzeichnis eintragen, am Ende ohne Backslash. Beispiel: E:\Music\VLC-Stream-Aufnahmen
	set "Zielverzeichnis=E:\Music\VLC-Stream-Aufnahmen"
	
    :: Programmliste (Fernsehen) für DVB-T-Sender (hier: Teutoburger Wald,Bielstein) 
	:: Die typische Reichweite eines DVB-T-Senders beträgt 40 km. Liste nach Empfängerstandort ergänzen.
	::   Senderfrequenzen in Deutschland siehe :: 1, Service-IDs eines Bouquets siehe :: 2 und :: 3 
	:: 1 http://www.dvb-t-portal.de/Regionen/index.php
	:: 2 https://www.vlc-forum.de/index.php/Thread/908-tv-tv-empfang-f%C3%BCr-dvb-t/
	:: 3 http://www.vdr-wiki.de/wiki/index.php/Kategorie:Channels.conf_DVBT    Frequenz: 1. Zahl, Service-ID: vor dem drittletzten Doppelpunkt stehende Zahl
	IF %Sender%==ARD   				set Frequenz=514 & set ServiceID=256
	IF %Sender%==ZDF   				set Frequenz=570 & set ServiceID=514
	IF %Sender%==3sat  				set Frequenz=570 & set ServiceID=515
	IF %Sender%==arte  				set Frequenz=514 & set ServiceID=2
	IF %Sender%==Phoenix  			set Frequenz=514 & set ServiceID=3
	IF %Sender%==EinsFestival   	set Frequenz=514 & set ServiceID=5
	IF %Sender%==ZDFinfo 			set Frequenz=570 & set ServiceID=516
	IF %Sender%==neoKiKa			set Frequenz=570 & set ServiceID=517
	IF %Sender%==MDR				set Frequenz=554 & set ServiceID=100
	IF %Sender%==NDR				set Frequenz=554 & set ServiceID=129
	IF %Sender%==SWR				set Frequenz=554 & set ServiceID=226
	IF %Sender%==WDR-BI				set Frequenz=554 & set ServiceID=258
	IF %Sender%==WDR-SG				set Frequenz=554 & set ServiceID=264
	IF %Sender%==Pro7Hannover		set Frequenz=658 & set ServiceID=16403
	IF %Sender%==ARDHamburg			set Frequenz=570 & set ServiceID=128
	IF %Sender%==VOXHamburg			set Frequenz=626 & set ServiceID=16418
	

	:: Programmliste für Internet-Radio
	:: URL unter Stationsnamen recherchieren
	IF %Sender%==BRKlassik	        set Frequenz=0   & set SenderURL=http://br-mp3-br-klassik-m.akacast.akamaistream.net/7/120/142693/v1/gnl.akacast.akamaistream.net/br_mp3_br-klassik_m
	IF %Sender%==WDR3				set Frequenz=0   & set SenderURL=http://wdr-3.akacast.akamaistream.net/7/47/119437/v1/gnl.akacast.akamaistream.net/wdr-3
	IF %Sender%==WDR4				set Frequenz=0   & set SenderURL=http://wdr-4.akacast.akamaistream.net/7/42/119438/v1/gnl.akacast.akamaistream.net/wdr-4
	IF %Sender%==RadioSwissClassic	set Frequenz=0   & set SenderURL=http://stream.srg-ssr.ch/m/rsc_de/mp3_128
	IF %Sender%==BBC1				set Frequenz=0   & set SenderURL=http://yradio.vtuner.com/pls/pls1357.m3u
	
	IF %Frequenz% GTR 0 (set "endg=ts") ELSE (set "endg=mp3")	
		
:: ### EINSTELLUNGEN-ENDE #########################################################################################################################

:: ### HINWEISE ###################################################################################################################################
	:: Dateiendung "txt" in "bat" ändern.
	:: Diese bat-Datei wendet sich an Nutzer mit Grundkenntnissen in Batch-Programmierung. Alle anderen beachten bitte: 
	:: Sie bearbeiten bei Ihren Eintragungen einen Programmcode. Änderungen außerhalb der Batch-Syntax führen zum Misserfolg.
	:: Videodateien werden als *.ts gespeichert, Audiodateien als *.mp3.
	:: Wenn Sie nicht in der Nähe des DVB-T-Senders Teutoburger-Wald-Bielstein (nahe Detmold) empfangen, ergänzen Sie die Fernseh-Programmliste um die
	:: interessierenden Stationen. Die vorhandene Liste kann (als Muster) bestehen bleiben.
	:: Sich zeitlich überlappende mp3-Aufnahmen sind mit mehreren, verschieden benannten bat-Dateien möglich.
	:: Für Sofortaufnahme das Datum des Vortags eintragen, Uhrzeit beliebig. 
	:: Tipp: Eintragungen einer zeitgesteuerten Aufnahme mittels kurzer Sofortaufnahme kontrollieren.
	:: Tipp: Bei DVB-T-Aufnahmen Anschließen des Empfängers (z. B. USB-Stick mit Antenne) nicht vergessen.
	:: Tipp: Speichern der Einträge vor dem Starten nicht vergessen!
	:: Tipp: Die vom Internet-Provider ausgelöste Zwangsunterbrechung (üblicherweise zwischen 3 und 5 Uhr nachts) bricht Aufnahmen ab. Das Intervall
    :: 	     kann mit der Router-Softwäre geändert werden.	
:: ### HINWEISE-ENDE ###############################################################################################################################

:: Wer hiernach etwas ändert, muss wissen, was er tut. ;)

set "Dateiname=%Dateiname%.%endg%"	                

title %~n0%~x0
echo Sender: %Sender%
echo Dateiname: %Dateiname% 
echo Datum Aufnahmebeginn: %DatumAufnahmebeginn%
echo Uhrzeit Aufnahmebeginn: %UhrzeitAufnahmebeginn% 
echo Aufnahmedauer in Minuten: %AufnahmedauerMinuten% 
echo Herunterfahren: %Herunterfahren% 
echo Zielverzeichnis: %Zielverzeichnis%

:: Format von %DatumAufnahmebeginn% auf JJJJ.MM.TT umstellen:
set "DatumAufnahmebeginn=%DatumAufnahmebeginn:~6,4%.%DatumAufnahmebeginn:~3,2%.%DatumAufnahmebeginn:~0,2%"
set "ZeitAufnahmebeginn=%DatumAufnahmebeginn%_%UhrzeitAufnahmebeginn%"
set /a "Frequenz = 1000000*%Frequenz%"
if "%Frequenz%" GTR "0" set SenderURL=dvb-t://frequency=%Frequenz%:bandwidth=0 :dvb-adapter=0 :live-caching=1000 :program=%ServiceID%
set /a "AufnahmedauerSekunden=60*%AufnahmedauerMinuten%" 


:WARTESCHLEIFE
	set "Uhrzeit=%time%"
	:: Format von %Uhrzeit% auch im Bereich einstelliger Stunden auf hh:mm setzen (microsoft-Syntax liefert dafür  0:00... 9:59 Uhr mit führendem Leerzeichen!):
    if "%Uhrzeit:~0,1%"==" "    set "Uhrzeit=0%time:~1,7%"
	set "Zeit=%date:~6,4%.%date:~3,2%.%date:~0,2%_%Uhrzeit%"
	:: Minütliche Anzeige des Aufnahmebeginns
	set "Sekunden=%Zeit:~17,2%"
	if "%Sekunden%" GEQ "55" echo Aufnahmebeginn am %DatumAufnahmebeginn% um %UhrzeitAufnahmebeginn% Uhr 
	if "%Zeit%" GEQ "%ZeitAufnahmebeginn%" (	 
		START "" "C:\Program Files (x86)\VideoLAN\VLC\vlc.exe" -vvv --run-time=%AufnahmedauerSekunden% %SenderURL% --sout=#file{dst="%Zielverzeichnis%\%Dateiname%"} vlc://quit			
	) else (
		:: Abfrageintervall der Warteschleife 
		timeout /T 5 /nobreak
		goto WARTESCHLEIFE
	)
:: Warteschleifenende

echo Aufnahme laeuft.  Aufnahme laeuft.  Aufnahme laeuft.  Aufnahme laeuft. ...
echo Sender: %Sender%
echo Dateiname: %Dateiname% 
echo Datum Aufnahmebeginn: %DatumAufnahmebeginn%
echo Uhrzeit Aufnahmebeginn: %UhrzeitAufnahmebeginn% 
echo Aufnahmedauer in Minuten: %AufnahmedauerMinuten% 
echo Herunterfahren: %Herunterfahren% 
echo Zielverzeichnis: %Zielverzeichnis%

timeout /T %AufnahmedauerSekunden%
timeout /T 10
if %Herunterfahren% EQU 1 (
	shutdown.exe /s /t 10
)		
:: Ende der batch-Datei